身份证运用--自动提取有关信息

通过身份证号码可以提取很多信息：输入身份证后自动提取“性别、出生日期、所在地区、星座、幸运日等。。。”

身份证运用-6_2010_10_19_20_32_14.mfd (134.97 KB, 下载次数: 131, 售价: 30 魔方币)

2010-10-19 20:34 上传

点击文件名下载附件

下面用魔方来实现一下。动画演示

游客，如果您要查看本帖隐藏内容请回复

今天修改完善校验公式。已下载的从新下载，不另收钱。哈哈

-----------------------------------------------------------------------------

修正错误：

在EXCEL中计算
MOD(434508,11)                            = 8

在魔方中计算
MOD(434508,11)                            = 7.9999

修改如下：
ROUND（MOD(434508,11)，0）       = 8

------------------------------------------------------------------------------

姓名	15位身份证		升级18位身份证
张三	210502841202094		210502198412020944
A	B	C	D	E	F
B*D	2^a	a	4	<=生成18位	18
8	2	1	4	15	17
36	4	2	9	14	16
0	8	3	0	13	15
32	16	4	2	12	14
0	32	5	0	11	13
128	64	6	2	10	12
128	128	7	1	9	11
1024	256	8	4	8	10
4096	512	9	8	7	9
9216	1024	10	9	添加9	8
2048	2048	11	1	添加1	7
8192	4096	12	2	6	6
0	8192	13	0	5	5
81920	16384	14	5	4	4
0	32768	15	0	3	3
65536	65536	16	1	2	2
262144	131072	17	2	1	1
434508	8	10X98765432	新身份证	原位数	新位数
求和	÷11余数8	第8+1个数据

说明如下:以B2单元格为例:   110221650815224
提取生日		1965-08-15
	公式
	1	=DATE(MID(B2,7,IF(LEN(B2)=18,4,2)),MID(B2,IF(LEN(B2)=18,11,9),2),MID(B2,IF(LEN(B2)=18,13,11),2))
	2	=--TEXT(MID(B2,7,6+(LEN(B2)=18)*2),"0-00-00")
	3	=TEXT(RIGHT(TEXT((0&MID(B2,7,11))-500,"1900-00-00,;!0"),10),"e-mm-dd;;;错误")
	4	=TEXT(TEXT((0&MID(B2,7,11))-500,"00-00-00,;!0"),"e-mm-dd;;;错误")
	5	=TEXT(MID(REPLACE(B2,7,,IF(LEN(B2)=15,19,)),7,8),"0000-00-00")
	6	=TEXT(REPLACE(MID(B2,7,6+(LEN(B2)=18)*2),1,,IF(LEN(MID(B2,7,6+(LEN(B2)=18)*2))=6,19,)),"0000-00-00")
	7	=TEXT(TEXT(MID(B2,7,6+(LEN(B2)=18)*2),"0-00-00"),"emmdd")
	8	=IF(LEN(B2)=15,"19"&MID(B2,7,6),MID(B2,7,8))
	9	=IF(LEN(B2)=15,19,"")&MID(B2,7,6+(LEN(B2)=18)*2)
提取性别		女
	公式
	1	=IF(MOD(IF(LEN(B2)=15,MID(B2,15,1),MID(B2,17,1)),2)=1,"男","女")
	2	=IF(MOD(RIGHT(LEFT(B2,17)),2),"男","女")
提取生肖		蛇
	公式	=MID("鼠牛虎兔龙蛇马羊猴鸡狗猪",MOD(YEAR(D2)-4,12)+1,1)
15位改18位		110221196508152247
	公式	=IF(LEN(B2)=15,REPLACE(B2,7,,19)&MID("10X98765432",MOD(SUM(MID(REPLACE(B2,7,,19),ROW(INDIRECT("1:17")),1)*2^(18-ROW(INDIRECT("1:17")))),11)+1,1),B2)
提取现在年龄		45
	公式	=IF(B2<>"",DATEDIF(TEXT((LEN(B2)=15)*19&MID(B2,7,6+(LEN(B2)=18)*2),"#-00-00"),TODAY(),"y"),)
号码正确否		TRUE
	公式	=OR(LEN(B2)=15,IF(LEN(B2)=18,MID("10X98765432",MOD(SUM(MID(B2,ROW(INDIRECT("1:17")),1)*2^(18-ROW(INDIRECT("1:17")))),11)+1,1)=RIGHT(B2)))
设置身份证输入单元格有效性（只能输入15位和18位数的正确的号码）
	公式	在数据有效性里选择允许自定义在公式里输入=OR(LEN(*)=15,IF(LEN(*)=18,MID("10X98765432",MOD(SUM(MID(*,ROW(INDIRECT("1:17")),1)*2^(18-ROW(INDIRECT("1:17")))),11)+1,1)=RIGHT(*)))
提取所属省份		北京市
	公式	=IF(B2<>"",VLOOKUP(LEFT(B2,2),地址码!B:C,2,),)
提取所属地区		(市辖区)昌平
	公式	=IF(B2<>"",VLOOKUP(LEFT(B2,6),地址码!B:C,2,),)
提取星座		獅子座 Leo
	公式	=LOOKUP(--TEXT($D2,"m.dd"),{0,"魔羯座 Capricorn";1.2,"水瓶座 Aquarius";2.19,"雙魚座 Pisces";3.21,"牡羊座 Aries";4.2,"金牛座 Taurus";5.21,"雙子座 Gemini";6.22,"巨蟹座 Cancer";7.23,"獅子座 Leo";8.23,"處女座 Virgo";9.23,"天秤座 Libra";10.24,"天蠍座 Scorpio";11.23,"射手座 Sagittarius";12.22,"魔羯座 Capricorn"})
提取幸运日		星期三
	公式	=LOOKUP(--TEXT($D2,"m.dd"),{0,"星期五";1.2,"星期六";2.19,"星期二";3.21,"星期二";4.2,"星期天";5.21,"星期三";6.22,"星期四";7.23,"星期三";8.23,"星期五";9.23,"星期四";10.24,"星期五";11.23,"星期一";12.22,"星期五"})

kanka ewrwewewewewewer

看看看看看看！！！！~~~~

这个很不错，急需要一份，怎么购买了，没 见着东西啊

6# zycblair
这个很不错，急需要一份，怎么购买了，没 见着东西啊

自动提取有关信息 1# fyzzg

学习
好好学习天天向上

这是网上找到的EXCEl电子表格制作的身份证利用系统。供大家参考！

运用下EXCEL表格先测试下公示，学习

这个很不错，急需要一份，怎么购买了，没 见着东西啊

点击下载：  身份证运用-6_2010_10_19_20_32_14.mfd

然后导入你的魔方。

太好了，我们要向你学习啊。

学习，，，，，，，，，，，，

省份怎么提取呢，郁闷死了弄了一晚了

tjfanglei 发表于 2011-10-23 00:30
省份怎么提取呢，郁闷死了弄了一晚了

通过【地址码】表单提取。

好东西，这些帖子对于我们这种还没有系统学习的人来说很有帮助的

学习学习学习学习学习学习学习学习学习学习

学习学习学习学习学习学习学习学习学习学习